LLVM Language Reference Manual
  1. Abstract
  2. Introduction
  3. Identifiers
  4. High Level Structure
    1. Module Structure
    2. Linkage Types
    3. Calling Conventions
    4. Global Variables
    5. Functions
    6. Module-Level Inline Assembly
  5. Type System
    1. Primitive Types
      1. Type Classifications
    2. Derived Types
      1. Array Type
      2. Function Type
      3. Pointer Type
      4. Structure Type
      5. Packed Type
      6. Opaque Type
  6. Constants
    1. Simple Constants
    2. Aggregate Constants
    3. Global Variable and Function Addresses
    4. Undefined Values
    5. Constant Expressions
  7. Other Values
    1. Inline Assembler Expressions
  8. Instruction Reference
    1. Terminator Instructions
      1. 'ret' Instruction
      2. 'br' Instruction
      3. 'switch' Instruction
      4. 'invoke' Instruction
      5. 'unwind' Instruction
      6. 'unreachable' Instruction
    2. Binary Operations
      1. 'add' Instruction
      2. 'sub' Instruction
      3. 'mul' Instruction
      4. 'div' Instruction
      5. 'rem' Instruction
      6. 'setcc' Instructions
    3. Bitwise Binary Operations
      1. 'and' Instruction
      2. 'or' Instruction
      3. 'xor' Instruction
      4. 'shl' Instruction
      5. 'shr' Instruction
    4. Vector Operations
      1. 'extractelement' Instruction
      2. 'insertelement' Instruction
      3. 'shufflevector' Instruction
    5. Memory Access Operations
      1. 'malloc' Instruction
      2. 'free' Instruction
      3. 'alloca' Instruction
      4. 'load' Instruction
      5. 'store' Instruction
      6. 'getelementptr' Instruction
    6. Other Operations
      1. 'phi' Instruction
      2. 'cast .. to' Instruction
      3. 'select' Instruction
      4. 'call' Instruction
      5. 'va_arg' Instruction
  9. Intrinsic Functions
    1. Variable Argument Handling Intrinsics
      1. 'llvm.va_start' Intrinsic
      2. 'llvm.va_end' Intrinsic
      3. 'llvm.va_copy' Intrinsic
    2. Accurate Garbage Collection Intrinsics
      1. 'llvm.gcroot' Intrinsic
      2. 'llvm.gcread' Intrinsic
      3. 'llvm.gcwrite' Intrinsic
    3. Code Generator Intrinsics
      1. 'llvm.returnaddress' Intrinsic
      2. 'llvm.frameaddress' Intrinsic
      3. 'llvm.stacksave' Intrinsic
      4. 'llvm.stackrestore' Intrinsic
      5. 'llvm.prefetch' Intrinsic
      6. 'llvm.pcmarker' Intrinsic
      7. llvm.readcyclecounter' Intrinsic
    4. Standard C Library Intrinsics
      1. 'llvm.memcpy.*' Intrinsic
      2. 'llvm.memmove.*' Intrinsic
      3. 'llvm.memset.*' Intrinsic
      4. 'llvm.isunordered.*' Intrinsic
      5. 'llvm.sqrt.*' Intrinsic
    5. Bit Manipulation Intrinsics
      1. 'llvm.bswap.*' Intrinsics
      2. 'llvm.ctpop.*' Intrinsic
      3. 'llvm.ctlz.*' Intrinsic
      4. 'llvm.cttz.*' Intrinsic
    6. Debugger intrinsics

Written by Chris Lattner and Vikram Adve

Abstract

This document is a reference manual for the LLVM assembly language. LLVM is an SSA based representation that provides type safety, low-level operations, flexibility, and the capability of representing 'all' high-level languages cleanly. It is the common code representation used throughout all phases of the LLVM compilation strategy.

Introduction

The LLVM code representation is designed to be used in three different forms: as an in-memory compiler IR, as an on-disk bytecode representation (suitable for fast loading by a Just-In-Time compiler), and as a human readable assembly language representation. This allows LLVM to provide a powerful intermediate representation for efficient compiler transformations and analysis, while providing a natural means to debug and visualize the transformations. The three different forms of LLVM are all equivalent. This document describes the human readable representation and notation.

The LLVM representation aims to be light-weight and low-level while being expressive, typed, and extensible at the same time. It aims to be a "universal IR" of sorts, by being at a low enough level that high-level ideas may be cleanly mapped to it (similar to how microprocessors are "universal IR's", allowing many source languages to be mapped to them). By providing type information, LLVM can be used as the target of optimizations: for example, through pointer analysis, it can be proven that a C automatic variable is never accessed outside of the current function... allowing it to be promoted to a simple SSA value instead of a memory location.

Well-Formedness

It is important to note that this document describes 'well formed' LLVM assembly language. There is a difference between what the parser accepts and what is considered 'well formed'. For example, the following instruction is syntactically okay, but not well formed:

  %x = add int 1, %x

...because the definition of %x does not dominate all of its uses. The LLVM infrastructure provides a verification pass that may be used to verify that an LLVM module is well formed. This pass is automatically run by the parser after parsing input assembly and by the optimizer before it outputs bytecode. The violations pointed out by the verifier pass indicate bugs in transformation passes or input to the parser.

Identifiers

LLVM uses three different forms of identifiers, for different purposes:

  1. Named values are represented as a string of characters with a '%' prefix. For example, %foo, %DivisionByZero, %a.really.long.identifier. The actual regular expression used is '%[a-zA-Z$._][a-zA-Z$._0-9]*'. Identifiers which require other characters in their names can be surrounded with quotes. In this way, anything except a " character can be used in a name.
  2. Unnamed values are represented as an unsigned numeric value with a '%' prefix. For example, %12, %2, %44.
  3. Constants, which are described in a section about constants, below.

LLVM requires that values start with a '%' sign for two reasons: Compilers don't need to worry about name clashes with reserved words, and the set of reserved words may be expanded in the future without penalty. Additionally, unnamed identifiers allow a compiler to quickly come up with a temporary variable without having to avoid symbol table conflicts.

Reserved words in LLVM are very similar to reserved words in other languages. There are keywords for different opcodes ('add', 'cast', 'ret', etc...), for primitive type names ('void', 'uint', etc...), and others. These reserved words cannot conflict with variable names, because none of them start with a '%' character.

Here is an example of LLVM code to multiply the integer variable '%X' by 8:

The easy way:

  %result = mul uint %X, 8

After strength reduction:

  %result = shl uint %X, ubyte 3

And the hard way:

  add uint %X, %X           ; yields {uint}:%0
  add uint %0, %0           ; yields {uint}:%1
  %result = add uint %1, %1

This last way of multiplying %X by 8 illustrates several important lexical features of LLVM:

  1. Comments are delimited with a ';' and go until the end of line.
  2. Unnamed temporaries are created when the result of a computation is not assigned to a named value.
  3. Unnamed temporaries are numbered sequentially

...and it also shows a convention that we follow in this document. When demonstrating instructions, we will follow an instruction with a comment that defines the type and name of value produced. Comments are shown in italic text.

High Level Structure
Module Structure

LLVM programs are composed of "Module"s, each of which is a translation unit of the input programs. Each module consists of functions, global variables, and symbol table entries. Modules may be combined together with the LLVM linker, which merges function (and global variable) definitions, resolves forward declarations, and merges symbol table entries. Here is an example of the "hello world" module:

; Declare the string constant as a global constant...
%.LC0 = internal constant [13 x sbyte] c"hello world\0A\00"          ; [13 x sbyte]*

; External declaration of the puts function
declare int %puts(sbyte*)                                            ; int(sbyte*)* 

; Definition of main function
int %main() {                                                        ; int()* 
        ; Convert [13x sbyte]* to sbyte *...
        %cast210 = getelementptr [13 x sbyte]* %.LC0, long 0, long 0 ; sbyte*

        ; Call puts function to write out the string to stdout...
        call int %puts(sbyte* %cast210)                              ; int
        ret int 0
}

This example is made up of a global variable named ".LC0", an external declaration of the "puts" function, and a function definition for "main".

In general, a module is made up of a list of global values, where both functions and global variables are global values. Global values are represented by a pointer to a memory location (in this case, a pointer to an array of char, and a pointer to a function), and have one of the following linkage types.

Linkage Types

All Global Variables and Functions have one of the following types of linkage:

internal
Global values with internal linkage are only directly accessible by objects in the current module. In particular, linking code into a module with an internal global value may cause the internal to be renamed as necessary to avoid collisions. Because the symbol is internal to the module, all references can be updated. This corresponds to the notion of the 'static' keyword in C, or the idea of "anonymous namespaces" in C++.
linkonce:
"linkonce" linkage is similar to internal linkage, with the twist that linking together two modules defining the same linkonce globals will cause one of the globals to be discarded. This is typically used to implement inline functions. Unreferenced linkonce globals are allowed to be discarded.
weak:
"weak" linkage is exactly the same as linkonce linkage, except that unreferenced weak globals may not be discarded. This is used to implement constructs in C such as "int X;" at global scope.
appending:
"appending" linkage may only be applied to global variables of pointer to array type. When two global variables with appending linkage are linked together, the two global arrays are appended together. This is the LLVM, typesafe, equivalent of having the system linker append together "sections" with identical names when .o files are linked.
externally visible:
If none of the above identifiers are used, the global is externally visible, meaning that it participates in linkage and can be used to resolve external symbol references.

For example, since the ".LC0" variable is defined to be internal, if another module defined a ".LC0" variable and was linked with this one, one of the two would be renamed, preventing a collision. Since "main" and "puts" are external (i.e., lacking any linkage declarations), they are accessible outside of the current module. It is illegal for a function declaration to have any linkage type other than "externally visible".

Calling Conventions

LLVM functions, calls and invokes can all have an optional calling convention specified for the call. The calling convention of any pair of dynamic caller/callee must match, or the behavior of the program is undefined. The following calling conventions are supported by LLVM, and more may be added in the future:

"ccc" - The C calling convention:
This calling convention (the default if no other calling convention is specified) matches the target C calling conventions. This calling convention supports varargs function calls and tolerates some mismatch in the declared prototype and implemented declaration of the function (as does normal C).
"fastcc" - The fast calling convention:
This calling convention attempts to make calls as fast as possible (e.g. by passing things in registers). This calling convention allows the target to use whatever tricks it wants to produce fast code for the target, without having to conform to an externally specified ABI. Implementations of this convention should allow arbitrary tail call optimization to be supported. This calling convention does not support varargs and requires the prototype of all callees to exactly match the prototype of the function definition.
"coldcc" - The cold calling convention:
This calling convention attempts to make code in the caller as efficient as possible under the assumption that the call is not commonly executed. As such, these calls often preserve all registers so that the call does not break any live ranges in the caller side. This calling convention does not support varargs and requires the prototype of all callees to exactly match the prototype of the function definition.
"cc <n>" - Numbered convention:
Any calling convention may be specified by number, allowing target-specific calling conventions to be used. Target specific calling conventions start at 64.

More calling conventions can be added/defined on an as-needed basis, to support pascal conventions or any other well-known target-independent convention.

Global Variables

Global variables define regions of memory allocated at compilation time instead of run-time. Global variables may optionally be initialized, may have an explicit section to be placed in, and may have an optional explicit alignment specified. A variable may be defined as a global "constant," which indicates that the contents of the variable will never be modified (enabling better optimization, allowing the global data to be placed in the read-only section of an executable, etc). Note that variables that need runtime initialization cannot be marked "constant" as there is a store to the variable.

LLVM explicitly allows declarations of global variables to be marked constant, even if the final definition of the global is not. This capability can be used to enable slightly better optimization of the program, but requires the language definition to guarantee that optimizations based on the 'constantness' are valid for the translation units that do not include the definition.

As SSA values, global variables define pointer values that are in scope (i.e. they dominate) all basic blocks in the program. Global variables always define a pointer to their "content" type because they describe a region of memory, and all memory objects in LLVM are accessed through pointers.

LLVM allows an explicit section to be specified for globals. If the target supports it, it will emit globals to the section specified.

An explicit alignment may be specified for a global. If not present, or if the alignment is set to zero, the alignment of the global is set by the target to whatever it feels convenient. If an explicit alignment is specified, the global is forced to have at least that much alignment. All alignments must be a power of 2.

Functions

LLVM function definitions consist of an optional linkage type, an optional calling convention, a return type, a function name, a (possibly empty) argument list, an optional section, an optional alignment, an opening curly brace, a list of basic blocks, and a closing curly brace. LLVM function declarations are defined with the "declare" keyword, an optional calling convention, a return type, a function name, a possibly empty list of arguments, and an optional alignment.

A function definition contains a list of basic blocks, forming the CFG for the function. Each basic block may optionally start with a label (giving the basic block a symbol table entry), contains a list of instructions, and ends with a terminator instruction (such as a branch or function return).

The first basic block in a program is special in two ways: it is immediately executed on entrance to the function, and it is not allowed to have predecessor basic blocks (i.e. there can not be any branches to the entry block of a function). Because the block can have no predecessors, it also cannot have any PHI nodes.

LLVM functions are identified by their name and type signature. Hence, two functions with the same name but different parameter lists or return values are considered different functions, and LLVM will resolve references to each appropriately.

LLVM allows an explicit section to be specified for functions. If the target supports it, it will emit functions to the section specified.

An explicit alignment may be specified for a function. If not present, or if the alignment is set to zero, the alignment of the function is set by the target to whatever it feels convenient. If an explicit alignment is specified, the function is forced to have at least that much alignment. All alignments must be a power of 2.

Module-Level Inline Assembly

Modules may contain "module-level inline asm" blocks, which corresponds to the GCC "file scope inline asm" blocks. These blocks are internally concatenated by LLVM and treated as a single unit, but may be separated in the .ll file if desired. The syntax is very simple:

  module asm "inline asm code goes here"
  module asm "more can go here"

The strings can contain any character by escaping non-printable characters. The escape sequence used is simply "\xx" where "xx" is the two digit hex code for the number.

The inline asm code is simply printed to the machine code .s file when assembly code is generated.

Type System

The LLVM type system is one of the most important features of the intermediate representation. Being typed enables a number of optimizations to be performed on the IR directly, without having to do extra analyses on the side before the transformation. A strong type system makes it easier to read the generated code and enables novel analyses and transformations that are not feasible to perform on normal three address code representations.

Primitive Types

The primitive types are the fundamental building blocks of the LLVM system. The current set of primitive types is as follows:

TypeDescription
voidNo value
ubyteUnsigned 8-bit value
ushortUnsigned 16-bit value
uintUnsigned 32-bit value
ulongUnsigned 64-bit value
float32-bit floating point value
labelBranch destination
TypeDescription
boolTrue or False value
sbyteSigned 8-bit value
shortSigned 16-bit value
intSigned 32-bit value
longSigned 64-bit value
double64-bit floating point value
Type Classifications

These different primitive types fall into a few useful classifications:

ClassificationTypes
signed sbyte, short, int, long, float, double
unsigned ubyte, ushort, uint, ulong
integer ubyte, sbyte, ushort, short, uint, int, ulong, long
integral bool, ubyte, sbyte, ushort, short, uint, int, ulong, long
floating point float, double
first class bool, ubyte, sbyte, ushort, short, uint, int, ulong, long,
float, double, pointer, packed

The first class types are perhaps the most important. Values of these types are the only ones which can be produced by instructions, passed as arguments, or used as operands to instructions. This means that all structures and arrays must be manipulated either by pointer or by component.

Derived Types

The real power in LLVM comes from the derived types in the system. This is what allows a programmer to represent arrays, functions, pointers, and other useful types. Note that these derived types may be recursive: For example, it is possible to have a two dimensional array.

Array Type
Overview:

The array type is a very simple derived type that arranges elements sequentially in memory. The array type requires a size (number of elements) and an underlying data type.

Syntax:
  [<# elements> x <elementtype>]

The number of elements is a constant integer value; elementtype may be any type with a size.

Examples:
[40 x int ]
[41 x int ]
[40 x uint]
Array of 40 integer values.
Array of 41 integer values.
Array of 40 unsigned integer values.

Here are some examples of multidimensional arrays:

[3 x [4 x int]]
[12 x [10 x float]]
[2 x [3 x [4 x uint]]]
3x4 array of integer values.
12x10 array of single precision floating point values.
2x3x4 array of unsigned integer values.

Note that 'variable sized arrays' can be implemented in LLVM with a zero length array. Normally, accesses past the end of an array are undefined in LLVM (e.g. it is illegal to access the 5th element of a 3 element array). As a special case, however, zero length arrays are recognized to be variable length. This allows implementation of 'pascal style arrays' with the LLVM type "{ int, [0 x float]}", for example.

Function Type
Overview:

The function type can be thought of as a function signature. It consists of a return type and a list of formal parameter types. Function types are usually used to build virtual function tables (which are structures of pointers to functions), for indirect function calls, and when defining a function.

The return type of a function type cannot be an aggregate type.

Syntax:
  <returntype> (<parameter list>)

...where '<parameter list>' is a comma-separated list of type specifiers. Optionally, the parameter list may include a type ..., which indicates that the function takes a variable number of arguments. Variable argument functions can access their arguments with the variable argument handling intrinsic functions.

Examples:
int (int)
float (int, int *) *
int (sbyte *, ...)
function taking an int, returning an int
Pointer to a function that takes an int and a pointer to int, returning float.
A vararg function that takes at least one pointer to sbyte (signed char in C), which returns an integer. This is the signature for printf in LLVM.
Structure Type
Overview:

The structure type is used to represent a collection of data members together in memory. The packing of the field types is defined to match the ABI of the underlying processor. The elements of a structure may be any type that has a size.

Structures are accessed using 'load and 'store' by getting a pointer to a field with the 'getelementptr' instruction.

Syntax:
  { <type list> }
Examples:
{ int, int, int }
{ float, int (int) * }
a triple of three int values
A pair, where the first element is a float and the second element is a pointer to a function that takes an int, returning an int.
Pointer Type
Overview:

As in many languages, the pointer type represents a pointer or reference to another object, which must live in memory.

Syntax:
  <type> *
Examples:
[4x int]*
int (int *) *
A pointer to array of four int values
A pointer to a function that takes an int*, returning an int.
Packed Type
Overview:

A packed type is a simple derived type that represents a vector of elements. Packed types are used when multiple primitive data are operated in parallel using a single instruction (SIMD). A packed type requires a size (number of elements) and an underlying primitive data type. Vectors must have a power of two length (1, 2, 4, 8, 16 ...). Packed types are considered first class.

Syntax:
  < <# elements> x <elementtype> >

The number of elements is a constant integer value; elementtype may be any integral or floating point type.

Examples:
<4 x int>
<8 x float>
<2 x uint>
Packed vector of 4 integer values.
Packed vector of 8 floating-point values.
Packed vector of 2 unsigned integer values.
Opaque Type
Overview:

Opaque types are used to represent unknown types in the system. This corresponds (for example) to the C notion of a foward declared structure type. In LLVM, opaque types can eventually be resolved to any type (not just a structure type).

Syntax:
  opaque
Examples:
opaque An opaque type.
Constants

LLVM has several different basic types of constants. This section describes them all and their syntax.

Simple Constants
Boolean constants
The two strings 'true' and 'false' are both valid constants of the bool type.
Integer constants
Standard integers (such as '4') are constants of the integer type. Negative numbers may be used with signed integer types.
Floating point constants
Floating point constants use standard decimal notation (e.g. 123.421), exponential notation (e.g. 1.23421e+2), or a more precise hexadecimal notation (see below). Floating point constants must have a floating point type.
Null pointer constants
The identifier 'null' is recognized as a null pointer constant and must be of pointer type.

The one non-intuitive notation for constants is the optional hexadecimal form of floating point constants. For example, the form 'double 0x432ff973cafa8000' is equivalent to (but harder to read than) 'double 4.5e+15'. The only time hexadecimal floating point constants are required (and the only time that they are generated by the disassembler) is when a floating point constant must be emitted but it cannot be represented as a decimal floating point number. For example, NaN's, infinities, and other special values are represented in their IEEE hexadecimal format so that assembly and disassembly do not cause any bits to change in the constants.

Aggregate Constants

Aggregate constants arise from aggregation of simple constants and smaller aggregate constants.

Structure constants
Structure constants are represented with notation similar to structure type definitions (a comma separated list of elements, surrounded by braces ({})). For example: "{ int 4, float 17.0, int* %G }", where "%G" is declared as "%G = external global int". Structure constants must have structure type, and the number and types of elements must match those specified by the type.
Array constants
Array constants are represented with notation similar to array type definitions (a comma separated list of elements, surrounded by square brackets ([])). For example: "[ int 42, int 11, int 74 ]". Array constants must have array type, and the number and types of elements must match those specified by the type.
Packed constants
Packed constants are represented with notation similar to packed type definitions (a comma separated list of elements, surrounded by less-than/greater-than's (<>)). For example: "< int 42, int 11, int 74, int 100 >". Packed constants must have packed type, and the number and types of elements must match those specified by the type.
Zero initialization
The string 'zeroinitializer' can be used to zero initialize a value to zero of any type, including scalar and aggregate types. This is often used to avoid having to print large zero initializers (e.g. for large arrays) and is always exactly equivalent to using explicit zero initializers.
Global Variable and Function Addresses

The addresses of global variables and functions are always implicitly valid (link-time) constants. These constants are explicitly referenced when the identifier for the global is used and always have pointer type. For example, the following is a legal LLVM file:

  %X = global int 17
  %Y = global int 42
  %Z = global [2 x int*] [ int* %X, int* %Y ]
Undefined Values

The string 'undef' is recognized as a type-less constant that has no specific value. Undefined values may be of any type and be used anywhere a constant is permitted.

Undefined values indicate to the compiler that the program is well defined no matter what value is used, giving the compiler more freedom to optimize.

Constant Expressions

Constant expressions are used to allow expressions involving other constants to be used as constants. Constant expressions may be of any first class type and may involve any LLVM operation that does not have side effects (e.g. load and call are not supported). The following is the syntax for constant expressions:

cast ( CST to TYPE )
Cast a constant to another type.
getelementptr ( CSTPTR, IDX0, IDX1, ... )
Perform the getelementptr operation on constants. As with the getelementptr instruction, the index list may have zero or more indexes, which are required to make sense for the type of "CSTPTR".
select ( COND, VAL1, VAL2 )
Perform the select operation on constants.
extractelement ( VAL, IDX )
Perform the extractelement operation on constants.
insertelement ( VAL, ELT, IDX )
Perform the insertelement operation on constants.
shufflevector ( VEC1, VEC2, IDXMASK )
Perform the shufflevector operation on constants.
OPCODE ( LHS, RHS )
Perform the specified operation of the LHS and RHS constants. OPCODE may be any of the binary or bitwise binary operations. The constraints on operands are the same as those for the corresponding instruction (e.g. no bitwise operations on floating point values are allowed).
Other Values
Inline Assembler Expressions

LLVM supports inline assembler expressions (as opposed to Module-Level Inline Assembly) through the use of a special value. This value represents the inline assembler as a string (containing the instructions to emit), a list of operand constraints (stored as a string), and a flag that indicates whether or not the inline asm expression has side effects. An example inline assembler expression is:

  int(int) asm "bswap $0", "=r,r"

Inline assembler expressions may only be used as the callee operand of a call instruction. Thus, typically we have:

  %X = call int asm "bswap $0", "=r,r"(int %Y)

Inline asms with side effects not visible in the constraint list must be marked as having side effects. This is done through the use of the 'sideeffect' keyword, like so:

  call void asm sideeffect "eieio", ""()

TODO: The format of the asm and constraints string still need to be documented here. Constraints on what can be done (e.g. duplication, moving, etc need to be documented).

Instruction Reference

The LLVM instruction set consists of several different classifications of instructions: terminator instructions, binary instructions, bitwise binary instructions, memory instructions, and other instructions.

Terminator Instructions

As mentioned previously, every basic block in a program ends with a "Terminator" instruction, which indicates which block should be executed after the current block is finished. These terminator instructions typically yield a 'void' value: they produce control flow, not values (the one exception being the 'invoke' instruction).

There are six different terminator instructions: the 'ret' instruction, the 'br' instruction, the 'switch' instruction, the 'invoke' instruction, the 'unwind' instruction, and the 'unreachable' instruction.

'ret' Instruction
Syntax:
  ret <type> <value>       ; Return a value from a non-void function
  ret void                 ; Return from void function
Overview:

The 'ret' instruction is used to return control flow (and a value) from a function back to the caller.

There are two forms of the 'ret' instruction: one that returns a value and then causes control flow, and one that just causes control flow to occur.

Arguments:

The 'ret' instruction may return any 'first class' type. Notice that a function is not well formed if there exists a 'ret' instruction inside of the function that returns a value that does not match the return type of the function.

Semantics:

When the 'ret' instruction is executed, control flow returns back to the calling function's context. If the caller is a "call" instruction, execution continues at the instruction after the call. If the caller was an "invoke" instruction, execution continues at the beginning of the "normal" destination block. If the instruction returns a value, that value shall set the call or invoke instruction's return value.

Example:
  ret int 5                       ; Return an integer value of 5
  ret void                        ; Return from a void function
'br' Instruction
Syntax:
  br bool <cond>, label <iftrue>, label <iffalse>
br label <dest> ; Unconditional branch
Overview:

The 'br' instruction is used to cause control flow to transfer to a different basic block in the current function. There are two forms of this instruction, corresponding to a conditional branch and an unconditional branch.

Arguments:

The conditional branch form of the 'br' instruction takes a single 'bool' value and two 'label' values. The unconditional form of the 'br' instruction takes a single 'label' value as a target.

Semantics:

Upon execution of a conditional 'br' instruction, the 'bool' argument is evaluated. If the value is true, control flows to the 'iftrue' label argument. If "cond" is false, control flows to the 'iffalse' label argument.

Example:
Test:
%cond = seteq int %a, %b
br bool %cond, label %IfEqual, label %IfUnequal
IfEqual:
ret int 1
IfUnequal:
ret int 0
'switch' Instruction
Syntax:
  switch <intty> <value>, label <defaultdest> [ <intty> <val>, label <dest> ... ]
Overview:

The 'switch' instruction is used to transfer control flow to one of several different places. It is a generalization of the 'br' instruction, allowing a branch to occur to one of many possible destinations.

Arguments:

The 'switch' instruction uses three parameters: an integer comparison value 'value', a default 'label' destination, and an array of pairs of comparison value constants and 'label's. The table is not allowed to contain duplicate constant entries.

Semantics:

The switch instruction specifies a table of values and destinations. When the 'switch' instruction is executed, this table is searched for the given value. If the value is found, control flow is transfered to the corresponding destination; otherwise, control flow is transfered to the default destination.

Implementation:

Depending on properties of the target machine and the particular switch instruction, this instruction may be code generated in different ways. For example, it could be generated as a series of chained conditional branches or with a lookup table.

Example:
 ; Emulate a conditional br instruction
 %Val = cast bool %value to int
 switch int %Val, label %truedest [int 0, label %falsedest ]

 ; Emulate an unconditional br instruction
 switch uint 0, label %dest [ ]

 ; Implement a jump table:
 switch uint %val, label %otherwise [ uint 0, label %onzero 
                                      uint 1, label %onone 
                                      uint 2, label %ontwo ]
'invoke' Instruction
Syntax:
  <result> = invoke [cconv] <ptr to function ty> %<function ptr val>(<function args>) 
                to label <normal label> except label <exception label>
Overview:

The 'invoke' instruction causes control to transfer to a specified function, with the possibility of control flow transfer to either the 'normal' label or the 'exception' label. If the callee function returns with the "ret" instruction, control flow will return to the "normal" label. If the callee (or any indirect callees) returns with the "unwind" instruction, control is interrupted and continued at the dynamically nearest "exception" label.

Arguments:

This instruction requires several arguments:

  1. The optional "cconv" marker indicates which calling convention the call should use. If none is specified, the call defaults to using C calling conventions.
  2. 'ptr to function ty': shall be the signature of the pointer to function value being invoked. In most cases, this is a direct function invocation, but indirect invokes are just as possible, branching off an arbitrary pointer to function value.
  3. 'function ptr val': An LLVM value containing a pointer to a function to be invoked.
  4. 'function args': argument list whose types match the function signature argument types. If the function signature indicates the function accepts a variable number of arguments, the extra arguments can be specified.
  5. 'normal label': the label reached when the called function executes a 'ret' instruction.
  6. 'exception label': the label reached when a callee returns with the unwind instruction.
Semantics:

This instruction is designed to operate as a standard 'call' instruction in most regards. The primary difference is that it establishes an association with a label, which is used by the runtime library to unwind the stack.

This instruction is used in languages with destructors to ensure that proper cleanup is performed in the case of either a longjmp or a thrown exception. Additionally, this is important for implementation of 'catch' clauses in high-level languages that support them.

Example:
  %retval = invoke int %Test(int 15)             to label %Continue
              except label %TestCleanup     ; {int}:retval set
  %retval = invoke coldcc int %Test(int 15)             to label %Continue
              except label %TestCleanup     ; {int}:retval set
'unwind' Instruction
Syntax:
  unwind
Overview:

The 'unwind' instruction unwinds the stack, continuing control flow at the first callee in the dynamic call stack which used an invoke instruction to perform the call. This is primarily used to implement exception handling.

Semantics:

The 'unwind' intrinsic causes execution of the current function to immediately halt. The dynamic call stack is then searched for the first invoke instruction on the call stack. Once found, execution continues at the "exceptional" destination block specified by the invoke instruction. If there is no invoke instruction in the dynamic call chain, undefined behavior results.

'unreachable' Instruction
Syntax:
  unreachable
Overview:

The 'unreachable' instruction has no defined semantics. This instruction is used to inform the optimizer that a particular portion of the code is not reachable. This can be used to indicate that the code after a no-return function cannot be reached, and other facts.

Semantics:

The 'unreachable' instruction has no defined semantics.

Binary Operations

Binary operators are used to do most of the computation in a program. They require two operands, execute an operation on them, and produce a single value. The operands might represent multiple data, as is the case with the packed data type. The result value of a binary operator is not necessarily the same type as its operands.

There are several different binary operators:

'add' Instruction
Syntax:
  <result> = add <ty> <var1>, <var2>   ; yields {ty}:result
Overview:

The 'add' instruction returns the sum of its two operands.

Arguments:

The two arguments to the 'add' instruction must be either integer or floating point values. This instruction can also take packed versions of the values. Both arguments must have identical types.

Semantics:

The value produced is the integer or floating point sum of the two operands.

Example:
  <result> = add int 4, %var          ; yields {int}:result = 4 + %var
'sub' Instruction
Syntax:
  <result> = sub <ty> <var1>, <var2>   ; yields {ty}:result
Overview:

The 'sub' instruction returns the difference of its two operands.

Note that the 'sub' instruction is used to represent the 'neg' instruction present in most other intermediate representations.

Arguments:

The two arguments to the 'sub' instruction must be either integer or floating point values. This instruction can also take packed versions of the values. Both arguments must have identical types.

Semantics:

The value produced is the integer or floating point difference of the two operands.

Example:
  <result> = sub int 4, %var          ; yields {int}:result = 4 - %var
  <result> = sub int 0, %val          ; yields {int}:result = -%var
'mul' Instruction
Syntax:
  <result> = mul <ty> <var1>, <var2>   ; yields {ty}:result
Overview:

The 'mul' instruction returns the product of its two operands.

Arguments:

The two arguments to the 'mul' instruction must be either integer or floating point values. This instruction can also take packed versions of the values. Both arguments must have identical types.

Semantics:

The value produced is the integer or floating point product of the two operands.

There is no signed vs unsigned multiplication. The appropriate action is taken based on the type of the operand.

Example:
  <result> = mul int 4, %var          ; yields {int}:result = 4 * %var
'div' Instruction
Syntax:
  <result> = div <ty> <var1>, <var2>   ; yields {ty}:result
Overview:

The 'div' instruction returns the quotient of its two operands.

Arguments:

The two arguments to the 'div' instruction must be either integer or floating point values. This instruction can also take packed versions of the values. Both arguments must have identical types.

Semantics:

The value produced is the integer or floating point quotient of the two operands.

Example:
  <result> = div int 4, %var          ; yields {int}:result = 4 / %var
'rem' Instruction
Syntax:
  <result> = rem <ty> <var1>, <var2>   ; yields {ty}:result
Overview:

The 'rem' instruction returns the remainder from the division of its two operands.

Arguments:

The two arguments to the 'rem' instruction must be either integer or floating point values. This instruction can also take packed versions of the values. Both arguments must have identical types.

Semantics:

This returns the remainder of a division (where the result has the same sign as the divisor), not the modulus (where the result has the same sign as the dividend) of a value. For more information about the difference, see The Math Forum.

Example:
  <result> = rem int 4, %var          ; yields {int}:result = 4 % %var
'setcc' Instructions
Syntax:
  <result> = seteq <ty> <var1>, <var2>   ; yields {bool}:result
  <result> = setne <ty> <var1>, <var2>   ; yields {bool}:result
  <result> = setlt <ty> <var1>, <var2>   ; yields {bool}:result
  <result> = setgt <ty> <var1>, <var2>   ; yields {bool}:result
  <result> = setle <ty> <var1>, <var2>   ; yields {bool}:result
  <result> = setge <ty> <var1>, <var2>   ; yields {bool}:result
Overview:

The 'setcc' family of instructions returns a boolean value based on a comparison of their two operands.

Arguments:

The two arguments to the 'setcc' instructions must be of first class type (it is not possible to compare 'label's, 'array's, 'structure' or 'void' values, etc...). Both arguments must have identical types.

Semantics:

The 'seteq' instruction yields a true 'bool' value if both operands are equal.
The 'setne' instruction yields a true 'bool' value if both operands are unequal.
The 'setlt' instruction yields a true 'bool' value if the first operand is less than the second operand.
The 'setgt' instruction yields a true 'bool' value if the first operand is greater than the second operand.
The 'setle' instruction yields a true 'bool' value if the first operand is less than or equal to the second operand.
The 'setge' instruction yields a true 'bool' value if the first operand is greater than or equal to the second operand.

Example:
  <result> = seteq int   4, 5        ; yields {bool}:result = false
  <result> = setne float 4, 5        ; yields {bool}:result = true
  <result> = setlt uint  4, 5        ; yields {bool}:result = true
  <result> = setgt sbyte 4, 5        ; yields {bool}:result = false
  <result> = setle sbyte 4, 5        ; yields {bool}:result = true
  <result> = setge sbyte 4, 5        ; yields {bool}:result = false
Bitwise Binary Operations

Bitwise binary operators are used to do various forms of bit-twiddling in a program. They are generally very efficient instructions and can commonly be strength reduced from other instructions. They require two operands, execute an operation on them, and produce a single value. The resulting value of the bitwise binary operators is always the same type as its first operand.

'and' Instruction
Syntax:
  <result> = and <ty> <var1>, <var2>   ; yields {ty}:result
Overview:

The 'and' instruction returns the bitwise logical and of its two operands.

Arguments:

The two arguments to the 'and' instruction must be integral values. Both arguments must have identical types.

Semantics:

The truth table used for the 'and' instruction is:

In0 In1 Out
0 0 0
0 1 0
1 0 0
1 1 1
Example:
  <result> = and int 4, %var         ; yields {int}:result = 4 & %var
  <result> = and int 15, 40          ; yields {int}:result = 8
  <result> = and int 4, 8            ; yields {int}:result = 0
'or' Instruction
Syntax:
  <result> = or <ty> <var1>, <var2>   ; yields {ty}:result
Overview:

The 'or' instruction returns the bitwise logical inclusive or of its two operands.

Arguments:

The two arguments to the 'or' instruction must be integral values. Both arguments must have identical types.

Semantics:

The truth table used for the 'or' instruction is:

In0 In1 Out
0 0 0
0 1 1
1 0 1
1 1 1
Example:
  <result> = or int 4, %var         ; yields {int}:result = 4 | %var
  <result> = or int 15, 40          ; yields {int}:result = 47
  <result> = or int 4, 8            ; yields {int}:result = 12
'xor' Instruction
Syntax:
  <result> = xor <ty> <var1>, <var2>   ; yields {ty}:result
Overview:

The 'xor' instruction returns the bitwise logical exclusive or of its two operands. The xor is used to implement the "one's complement" operation, which is the "~" operator in C.

Arguments:

The two arguments to the 'xor' instruction must be integral values. Both arguments must have identical types.

Semantics:

The truth table used for the 'xor' instruction is:

In0 In1 Out
0 0 0
0 1 1
1 0 1
1 1 0

Example:
  <result> = xor int 4, %var         ; yields {int}:result = 4 ^ %var
  <result> = xor int 15, 40          ; yields {int}:result = 39
  <result> = xor int 4, 8            ; yields {int}:result = 12
  <result> = xor int %V, -1          ; yields {int}:result = ~%V
'shl' Instruction
Syntax:
  <result> = shl <ty> <var1>, ubyte <var2>   ; yields {ty}:result
Overview:

The 'shl' instruction returns the first operand shifted to the left a specified number of bits.

Arguments:

The first argument to the 'shl' instruction must be an integer type. The second argument must be an 'ubyte' type.

Semantics:

The value produced is var1 * 2var2.

Example:
  <result> = shl int 4, ubyte %var   ; yields {int}:result = 4 << %var
  <result> = shl int 4, ubyte 2      ; yields {int}:result = 16
  <result> = shl int 1, ubyte 10     ; yields {int}:result = 1024
'shr' Instruction
Syntax:
  <result> = shr <ty> <var1>, ubyte <var2>   ; yields {ty}:result
Overview:

The 'shr' instruction returns the first operand shifted to the right a specified number of bits.

Arguments:

The first argument to the 'shr' instruction must be an integer type. The second argument must be an 'ubyte' type.

Semantics:

If the first argument is a signed type, the most significant bit is duplicated in the newly free'd bit positions. If the first argument is unsigned, zero bits shall fill the empty positions.

Example:
  <result> = shr int 4, ubyte %var   ; yields {int}:result = 4 >> %var
  <result> = shr uint 4, ubyte 1     ; yields {uint}:result = 2
  <result> = shr int 4, ubyte 2      ; yields {int}:result = 1
  <result> = shr sbyte 4, ubyte 3    ; yields {sbyte}:result = 0
  <result> = shr sbyte -2, ubyte 1   ; yields {sbyte}:result = -1
Vector Operations

LLVM supports several instructions to represent vector operations in a target-independent manner. This instructions cover the element-access and vector-specific operations needed to process vectors effectively. While LLVM does directly support these vector operations, many sophisticated algorithms will want to use target-specific intrinsics to take full advantage of a specific target.

'extractelement' Instruction
Syntax:
  <result> = extractelement <n x <ty>> <val>, uint <idx>    ; yields <ty>
Overview:

The 'extractelement' instruction extracts a single scalar element from a packed vector at a specified index.

Arguments:

The first operand of an 'extractelement' instruction is a value of packed type. The second operand is an index indicating the position from which to extract the element. The index may be a variable.

Semantics:

The result is a scalar of the same type as the element type of val. Its value is the value at position idx of val. If idx exceeds the length of val, the results are undefined.

Example:
  %result = extractelement <4 x int> %vec, uint 0    ; yields int
'insertelement' Instruction
Syntax:
  <result> = insertelement <n x <ty>> <val>, <ty> <elt>, uint <idx>    ; yields <n x <ty>>
Overview:

The 'insertelement' instruction inserts a scalar element into a packed vector at a specified index.

Arguments:

The first operand of an 'insertelement' instruction is a value of packed type. The second operand is a scalar value whose type must equal the element type of the first operand. The third operand is an index indicating the position at which to insert the value. The index may be a variable.

Semantics:

The result is a packed vector of the same type as val. Its element values are those of val except at position idx, where it gets the value elt. If idx exceeds the length of val, the results are undefined.

Example:
  %result = insertelement <4 x int> %vec, int 1, uint 0    ; yields <4 x int>
'shufflevector' Instruction
Syntax:
  <result> = shufflevector <n x <ty>> <v1>, <n x <ty>> <v2>, <n x uint> <mask>    ; yields <n x <ty>>
Overview:

The 'shufflevector' instruction constructs a permutation of elements from two input vectors, returning a vector of the same type.

Arguments:

The first two operands of a 'shufflevector' instruction are vectors with types that match each other and types that match the result of the instruction. The third argument is a shuffle mask, which has the same number of elements as the other vector type, but whose element type is always 'uint'.

The shuffle mask operand is required to be a constant vector with either constant integer or undef values.

Semantics:

The elements of the two input vectors are numbered from left to right across both of the vectors. The shuffle mask operand specifies, for each element of the result vector, which element of the two input registers the result element gets. The element selector may be undef (meaning "don't care") and the second operand may be undef if performing a shuffle from only one vector.

Example:
  %result = shufflevector <4 x int> %v1, <4 x int> %v2, 
                          <4 x uint> <uint 0, uint 4, uint 1, uint 5>    ; yields <4 x int>
  %result = shufflevector <4 x int> %v1, <4 x int> undef, 
                          <4 x uint> <uint 0, uint 1, uint 2, uint 3>  ; yields <4 x int> - Identity shuffle.
Memory Access Operations

A key design point of an SSA-based representation is how it represents memory. In LLVM, no memory locations are in SSA form, which makes things very simple. This section describes how to read, write, allocate, and free memory in LLVM.

'malloc' Instruction
Syntax:
  <result> = malloc <type>[, uint <NumElements>][, align <alignment>]     ; yields {type*}:result
Overview:

The 'malloc' instruction allocates memory from the system heap and returns a pointer to it.

Arguments:

The 'malloc' instruction allocates sizeof(<type>)*NumElements bytes of memory from the operating system and returns a pointer of the appropriate type to the program. If "NumElements" is specified, it is the number of elements allocated. If an alignment is specified, the value result of the allocation is guaranteed to be aligned to at least that boundary. If not specified, or if zero, the target can choose to align the allocation on any convenient boundary.

'type' must be a sized type.

Semantics:

Memory is allocated using the system "malloc" function, and a pointer is returned.

Example:
  %array  = malloc [4 x ubyte ]                    ; yields {[%4 x ubyte]*}:array

  %size   = add uint 2, 2                          ; yields {uint}:size = uint 4
  %array1 = malloc ubyte, uint 4                   ; yields {ubyte*}:array1
  %array2 = malloc [12 x ubyte], uint %size        ; yields {[12 x ubyte]*}:array2
  %array3 = malloc int, uint 4, align 1024         ; yields {int*}:array3
  %array4 = malloc int, align 1024                 ; yields {int*}:array4
'free' Instruction
Syntax:
  free <type> <value>                              ; yields {void}
Overview:

The 'free' instruction returns memory back to the unused memory heap to be reallocated in the future.

Arguments:

'value' shall be a pointer value that points to a value that was allocated with the 'malloc' instruction.

Semantics:

Access to the memory pointed to by the pointer is no longer defined after this instruction executes.

Example:
  %array  = malloc [4 x ubyte]                    ; yields {[4 x ubyte]*}:array
            free   [4 x ubyte]* %array
'alloca' Instruction
Syntax:
  <result> = alloca <type>[, uint <NumElements>][, align <alignment>]     ; yields {type*}:result
Overview:

The 'alloca' instruction allocates memory on the current stack frame of the procedure that is live until the current function returns to its caller.

Arguments:

The 'alloca' instruction allocates sizeof(<type>)*NumElements bytes of memory on the runtime stack, returning a pointer of the appropriate type to the program. If "NumElements" is specified, it is the number of elements allocated. If an alignment is specified, the value result of the allocation is guaranteed to be aligned to at least that boundary. If not specified, or if zero, the target can choose to align the allocation on any convenient boundary.

'type' may be any sized type.

Semantics:

Memory is allocated; a pointer is returned. 'alloca'd memory is automatically released when the function returns. The 'alloca' instruction is commonly used to represent automatic variables that must have an address available. When the function returns (either with the ret or unwind instructions), the memory is reclaimed.

Example:
  %ptr = alloca int                              ; yields {int*}:ptr
  %ptr = alloca int, uint 4                      ; yields {int*}:ptr
  %ptr = alloca int, uint 4, align 1024          ; yields {int*}:ptr
  %ptr = alloca int, align 1024                  ; yields {int*}:ptr
'load' Instruction
Syntax:
  <result> = load <ty>* <pointer>
<result> = volatile load <ty>* <pointer>
Overview:

The 'load' instruction is used to read from memory.

Arguments:

The argument to the 'load' instruction specifies the memory address from which to load. The pointer must point to a first class type. If the load is marked as volatile, then the optimizer is not allowed to modify the number or order of execution of this load with other volatile load and store instructions.

Semantics:

The location of memory pointed to is loaded.

Examples:
  %ptr = alloca int                               ; yields {int*}:ptr
  store int 3, int* %ptr                          ; yields {void}
  %val = load int* %ptr                           ; yields {int}:val = int 3
'store' Instruction
Syntax:
  store <ty> <value>, <ty>* <pointer>                   ; yields {void}
  volatile store <ty> <value>, <ty>* <pointer>                   ; yields {void}
Overview:

The 'store' instruction is used to write to memory.

Arguments:

There are two arguments to the 'store' instruction: a value to store and an address in which to store it. The type of the '<pointer>' operand must be a pointer to the type of the '<value>' operand. If the store is marked as volatile, then the optimizer is not allowed to modify the number or order of execution of this store with other volatile load and store instructions.

Semantics:

The contents of memory are updated to contain '<value>' at the location specified by the '<pointer>' operand.

Example:
  %ptr = alloca int                               ; yields {int*}:ptr
  store int 3, int* %ptr                          ; yields {void}
  %val = load int* %ptr                           ; yields {int}:val = int 3
'getelementptr' Instruction
Syntax:
  <result> = getelementptr <ty>* <ptrval>{, <ty> <idx>}*
Overview:

The 'getelementptr' instruction is used to get the address of a subelement of an aggregate data structure.

Arguments:

This instruction takes a list of integer constants that indicate what elements of the aggregate object to index to. The actual types of the arguments provided depend on the type of the first pointer argument. The 'getelementptr' instruction is used to index down through the type levels of a structure or to a specific index in an array. When indexing into a structure, only uint integer constants are allowed. When indexing into an array or pointer, int and long indexes are allowed of any sign.

For example, let's consider a C code fragment and how it gets compiled to LLVM:

  struct RT {
    char A;
    int B[10][20];
    char C;
  };
  struct ST {
    int X;
    double Y;
    struct RT Z;
  };

  int *foo(struct ST *s) {
    return &s[1].Z.B[5][13];
  }

The LLVM code generated by the GCC frontend is:

  %RT = type { sbyte, [10 x [20 x int]], sbyte }
  %ST = type { int, double, %RT }

  implementation

  int* %foo(%ST* %s) {
  entry:
    %reg = getelementptr %ST* %s, int 1, uint 2, uint 1, int 5, int 13
    ret int* %reg
  }
Semantics:

The index types specified for the 'getelementptr' instruction depend on the pointer type that is being indexed into. Pointer and array types require uint, int, ulong, or long values, and structure types require uint constants.

In the example above, the first index is indexing into the '%ST*' type, which is a pointer, yielding a '%ST' = '{ int, double, %RT }' type, a structure. The second index indexes into the third element of the structure, yielding a '%RT' = '{ sbyte, [10 x [20 x int]], sbyte }' type, another structure. The third index indexes into the second element of the structure, yielding a '[10 x [20 x int]]' type, an array. The two dimensions of the array are subscripted into, yielding an 'int' type. The 'getelementptr' instruction returns a pointer to this element, thus computing a value of 'int*' type.

Note that it is perfectly legal to index partially through a structure, returning a pointer to an inner element. Because of this, the LLVM code for the given testcase is equivalent to:

  int* %foo(%ST* %s) {
    %t1 = getelementptr %ST* %s, int 1                        ; yields %ST*:%t1
    %t2 = getelementptr %ST* %t1, int 0, uint 2               ; yields %RT*:%t2
    %t3 = getelementptr %RT* %t2, int 0, uint 1               ; yields [10 x [20 x int]]*:%t3
    %t4 = getelementptr [10 x [20 x int]]* %t3, int 0, int 5  ; yields [20 x int]*:%t4
    %t5 = getelementptr [20 x int]* %t4, int 0, int 13        ; yields int*:%t5
    ret int* %t5
  }

Note that it is undefined to access an array out of bounds: array and pointer indexes must always be within the defined bounds of the array type. The one exception for this rules is zero length arrays. These arrays are defined to be accessible as variable length arrays, which requires access beyond the zero'th element.

Example:
    ; yields [12 x ubyte]*:aptr
    %aptr = getelementptr {int, [12 x ubyte]}* %sptr, long 0, uint 1
Other Operations

The instructions in this category are the "miscellaneous" instructions, which defy better classification.

'phi' Instruction
Syntax:
  <result> = phi <ty> [ <val0>, <label0>], ...
Overview:

The 'phi' instruction is used to implement the φ node in the SSA graph representing the function.

Arguments:

The type of the incoming values are specified with the first type field. After this, the 'phi' instruction takes a list of pairs as arguments, with one pair for each predecessor basic block of the current block. Only values of first class type may be used as the value arguments to the PHI node. Only labels may be used as the label arguments.

There must be no non-phi instructions between the start of a basic block and the PHI instructions: i.e. PHI instructions must be first in a basic block.

Semantics:

At runtime, the 'phi' instruction logically takes on the value specified by the parameter, depending on which basic block we came from in the last terminator instruction.

Example:
Loop:       ; Infinite loop that counts from 0 on up...
%indvar = phi uint [ 0, %LoopHeader ], [ %nextindvar, %Loop ]
%nextindvar = add uint %indvar, 1
br label %Loop
'cast .. to' Instruction
Syntax:
  <result> = cast <ty> <value> to <ty2>             ; yields ty2
Overview:

The 'cast' instruction is used as the primitive means to convert integers to floating point, change data type sizes, and break type safety (by casting pointers).

Arguments:

The 'cast' instruction takes a value to cast, which must be a first class value, and a type to cast it to, which must also be a first class type.

Semantics:

This instruction follows the C rules for explicit casts when determining how the data being cast must change to fit in its new container.

When casting to bool, any value that would be considered true in the context of a C 'if' condition is converted to the boolean 'true' values, all else are 'false'.

When extending an integral value from a type of one signness to another (for example 'sbyte' to 'ulong'), the value is sign-extended if the source value is signed, and zero-extended if the source value is unsigned. bool values are always zero extended into either zero or one.

Example:
  %X = cast int 257 to ubyte              ; yields ubyte:1
  %Y = cast int 123 to bool               ; yields bool:true
'select' Instruction
Syntax:
  <result> = select bool <cond>, <ty> <val1>, <ty> <val2>             ; yields ty
Overview:

The 'select' instruction is used to choose one value based on a condition, without branching.

Arguments:

The 'select' instruction requires a boolean value indicating the condition, and two values of the same first class type.

Semantics:

If the boolean condition evaluates to true, the instruction returns the first value argument; otherwise, it returns the second value argument.

Example:
  %X = select bool true, ubyte 17, ubyte 42          ; yields ubyte:17
'call' Instruction
Syntax:
  <result> = [tail] call [cconv] <ty>* <fnptrval>(<param list>)
Overview:

The 'call' instruction represents a simple function call.

Arguments:

This instruction requires several arguments:

  1. The optional "tail" marker indicates whether the callee function accesses any allocas or varargs in the caller. If the "tail" marker is present, the function call is eligible for tail call optimization. Note that calls may be marked "tail" even if they do not occur before a ret instruction.

  2. The optional "cconv" marker indicates which calling convention the call should use. If none is specified, the call defaults to using C calling conventions.

  3. 'ty': shall be the signature of the pointer to function value being invoked. The argument types must match the types implied by this signature. This type can be omitted if the function is not varargs and if the function type does not return a pointer to a function.

  4. 'fnptrval': An LLVM value containing a pointer to a function to be invoked. In most cases, this is a direct function invocation, but indirect calls are just as possible, calling an arbitrary pointer to function value.

  5. 'function args': argument list whose types match the function signature argument types. All arguments must be of first class type. If the function signature indicates the function accepts a variable number of arguments, the extra arguments can be specified.

Semantics:

The 'call' instruction is used to cause control flow to transfer to a specified function, with its incoming arguments bound to the specified values. Upon a 'ret' instruction in the called function, control flow continues with the instruction after the function call, and the return value of the function is bound to the result argument. This is a simpler case of the invoke instruction.

Example:
  %retval = call int %test(int %argc)
  call int(sbyte*, ...) *%printf(sbyte* %msg, int 12, sbyte 42);
  %X = tail call int %foo()
  %Y = tail call fastcc int %foo()
'va_arg' Instruction
Syntax:
  <resultval> = va_arg <va_list*> <arglist>, <argty>
Overview:

The 'va_arg' instruction is used to access arguments passed through the "variable argument" area of a function call. It is used to implement the va_arg macro in C.

Arguments:

This instruction takes a va_list* value and the type of the argument. It returns a value of the specified argument type and increments the va_list to point to the next argument. Again, the actual type of va_list is target specific.

Semantics:

The 'va_arg' instruction loads an argument of the specified type from the specified va_list and causes the va_list to point to the next argument. For more information, see the variable argument handling Intrinsic Functions.

It is legal for this instruction to be called in a function which does not take a variable number of arguments, for example, the vfprintf function.

va_arg is an LLVM instruction instead of an intrinsic function because it takes a type as an argument.

Example:

See the variable argument processing section.

Intrinsic Functions

LLVM supports the notion of an "intrinsic function". These functions have well known names and semantics and are required to follow certain restrictions. Overall, these instructions represent an extension mechanism for the LLVM language that does not require changing all of the transformations in LLVM to add to the language (or the bytecode reader/writer, the parser, etc...).

Intrinsic function names must all start with an "llvm." prefix. This prefix is reserved in LLVM for intrinsic names; thus, functions may not be named this. Intrinsic functions must always be external functions: you cannot define the body of intrinsic functions. Intrinsic functions may only be used in call or invoke instructions: it is illegal to take the address of an intrinsic function. Additionally, because intrinsic functions are part of the LLVM language, it is required that they all be documented here if any are added.

To learn how to add an intrinsic function, please see the Extending LLVM Guide.

Variable Argument Handling Intrinsics

Variable argument support is defined in LLVM with the va_arg instruction and these three intrinsic functions. These functions are related to the similarly named macros defined in the <stdarg.h> header file.

All of these functions operate on arguments that use a target-specific value type "va_list". The LLVM assembly language reference manual does not define what this type is, so all transformations should be prepared to handle intrinsics with any type used.

This example shows how the vanext instruction and the variable argument handling intrinsic functions are used.

int %test(int %X, ...) {
  ; Initialize variable argument processing
  %ap = alloca sbyte*
  call void %llvm.va_start(sbyte** %ap)

  ; Read a single integer argument
  %tmp = va_arg sbyte** %ap, int

  ; Demonstrate usage of llvm.va_copy and llvm.va_end
  %aq = alloca sbyte*
  call void %llvm.va_copy(sbyte** %aq, sbyte** %ap)
  call void %llvm.va_end(sbyte** %aq)

  ; Stop processing of arguments.
  call void %llvm.va_end(sbyte** %ap)
  ret int %tmp
}
'llvm.va_start' Intrinsic
Syntax:
  declare void %llvm.va_start(<va_list>* <arglist>)
Overview:

The 'llvm.va_start' intrinsic initializes *<arglist> for subsequent use by va_arg.

Arguments:

The argument is a pointer to a va_list element to initialize.

Semantics:

The 'llvm.va_start' intrinsic works just like the va_start macro available in C. In a target-dependent way, it initializes the va_list element the argument points to, so that the next call to va_arg will produce the first variable argument passed to the function. Unlike the C va_start macro, this intrinsic does not need to know the last argument of the function, the compiler can figure that out.

'llvm.va_end' Intrinsic
Syntax:
  declare void %llvm.va_end(<va_list*> <arglist>)
Overview:

The 'llvm.va_end' intrinsic destroys <arglist> which has been initialized previously with llvm.va_start or llvm.va_copy.

Arguments:

The argument is a va_list to destroy.

Semantics:

The 'llvm.va_end' intrinsic works just like the va_end macro available in C. In a target-dependent way, it destroys the va_list. Calls to llvm.va_start and llvm.va_copy must be matched exactly with calls to llvm.va_end.

'llvm.va_copy' Intrinsic
Syntax:
  declare void %llvm.va_copy(<va_list>* <destarglist>,
                                          <va_list>* <srcarglist>)
Overview:

The 'llvm.va_copy' intrinsic copies the current argument position from the source argument list to the destination argument list.

Arguments:

The first argument is a pointer to a va_list element to initialize. The second argument is a pointer to a va_list element to copy from.

Semantics:

The 'llvm.va_copy' intrinsic works just like the va_copy macro available in C. In a target-dependent way, it copies the source va_list element into the destination list. This intrinsic is necessary because the llvm.va_begin intrinsic may be arbitrarily complex and require memory allocation, for example.

Accurate Garbage Collection Intrinsics

LLVM support for Accurate Garbage Collection requires the implementation and generation of these intrinsics. These intrinsics allow identification of GC roots on the stack, as well as garbage collector implementations that require read and write barriers. Front-ends for type-safe garbage collected languages should generate these intrinsics to make use of the LLVM garbage collectors. For more details, see Accurate Garbage Collection with LLVM.

'llvm.gcroot' Intrinsic
Syntax:
  declare void %llvm.gcroot(<ty>** %ptrloc, <ty2>* %metadata)
Overview:

The 'llvm.gcroot' intrinsic declares the existence of a GC root to the code generator, and allows some metadata to be associated with it.

Arguments:

The first argument specifies the address of a stack object that contains the root pointer. The second pointer (which must be either a constant or a global value address) contains the meta-data to be associated with the root.

Semantics:

At runtime, a call to this intrinsics stores a null pointer into the "ptrloc" location. At compile-time, the code generator generates information to allow the runtime to find the pointer at GC safe points.

'llvm.gcread' Intrinsic
Syntax:
  declare sbyte* %llvm.gcread(sbyte* %ObjPtr, sbyte** %Ptr)
Overview:

The 'llvm.gcread' intrinsic identifies reads of references from heap locations, allowing garbage collector implementations that require read barriers.

Arguments:

The second argument is the address to read from, which should be an address allocated from the garbage collector. The first object is a pointer to the start of the referenced object, if needed by the language runtime (otherwise null).

Semantics:

The 'llvm.gcread' intrinsic has the same semantics as a load instruction, but may be replaced with substantially more complex code by the garbage collector runtime, as needed.

'llvm.gcwrite' Intrinsic
Syntax:
  declare void %llvm.gcwrite(sbyte* %P1, sbyte* %Obj, sbyte** %P2)
Overview:

The 'llvm.gcwrite' intrinsic identifies writes of references to heap locations, allowing garbage collector implementations that require write barriers (such as generational or reference counting collectors).

Arguments:

The first argument is the reference to store, the second is the start of the object to store it to, and the third is the address of the field of Obj to store to. If the runtime does not require a pointer to the object, Obj may be null.

Semantics:

The 'llvm.gcwrite' intrinsic has the same semantics as a store instruction, but may be replaced with substantially more complex code by the garbage collector runtime, as needed.

Code Generator Intrinsics

These intrinsics are provided by LLVM to expose special features that may only be implemented with code generator support.

'llvm.returnaddress' Intrinsic
Syntax:
  declare sbyte *%llvm.returnaddress(uint <level>)
Overview:

The 'llvm.returnaddress' intrinsic returns a target-specific value indicating the return address of the current function or one of its callers.

Arguments:

The argument to this intrinsic indicates which function to return the address for. Zero indicates the calling function, one indicates its caller, etc. The argument is required to be a constant integer value.

Semantics:

The 'llvm.returnaddress' intrinsic either returns a pointer indicating the return address of the specified call frame, or zero if it cannot be identified. The value returned by this intrinsic is likely to be incorrect or 0 for arguments other than zero, so it should only be used for debugging purposes.

Note that calling this intrinsic does not prevent function inlining or other aggressive transformations, so the value returned may not be that of the obvious source-language caller.

'llvm.frameaddress' Intrinsic
Syntax:
  declare sbyte *%llvm.frameaddress(uint <level>)
Overview:

The 'llvm.frameaddress' intrinsic returns the target-specific frame pointer value for the specified stack frame.

Arguments:

The argument to this intrinsic indicates which function to return the frame pointer for. Zero indicates the calling function, one indicates its caller, etc. The argument is required to be a constant integer value.

Semantics:

The 'llvm.frameaddress' intrinsic either returns a pointer indicating the frame address of the specified call frame, or zero if it cannot be identified. The value returned by this intrinsic is likely to be incorrect or 0 for arguments other than zero, so it should only be used for debugging purposes.

Note that calling this intrinsic does not prevent function inlining or other aggressive transformations, so the value returned may not be that of the obvious source-language caller.

'llvm.stacksave' Intrinsic
Syntax:
  declare sbyte *%llvm.stacksave()
Overview:

The 'llvm.stacksave' intrinsic is used to remember the current state of the function stack, for use with llvm.stackrestore. This is useful for implementing language features like scoped automatic variable sized arrays in C99.

Semantics:

This intrinsic returns a opaque pointer value that can be passed to llvm.stackrestore. When an llvm.stackrestore intrinsic is executed with a value saved from llvm.stacksave, it effectively restores the state of the stack to the state it was in when the llvm.stacksave intrinsic executed. In practice, this pops any alloca blocks from the stack that were allocated after the llvm.stacksave was executed.

'llvm.stackrestore' Intrinsic
Syntax:
  declare void %llvm.stackrestore(sbyte* %ptr)
Overview:

The 'llvm.stackrestore' intrinsic is used to restore the state of the function stack to the state it was in when the corresponding llvm.stacksave intrinsic executed. This is useful for implementing language features like scoped automatic variable sized arrays in C99.

Semantics:

See the description for llvm.stacksave.

'llvm.prefetch' Intrinsic
Syntax:
  declare void %llvm.prefetch(sbyte * <address>,
                                uint <rw>, uint <locality>)
Overview:

The 'llvm.prefetch' intrinsic is a hint to the code generator to insert a prefetch instruction if supported; otherwise, it is a noop. Prefetches have no effect on the behavior of the program but can change its performance characteristics.

Arguments:

address is the address to be prefetched, rw is the specifier determining if the fetch should be for a read (0) or write (1), and locality is a temporal locality specifier ranging from (0) - no locality, to (3) - extremely local keep in cache. The rw and locality arguments must be constant integers.

Semantics:

This intrinsic does not modify the behavior of the program. In particular, prefetches cannot trap and do not produce a value. On targets that support this intrinsic, the prefetch can provide hints to the processor cache for better performance.

'llvm.pcmarker' Intrinsic
Syntax:
  declare void %llvm.pcmarker( uint <id> )
Overview:

The 'llvm.pcmarker' intrinsic is a method to export a Program Counter (PC) in a region of code to simulators and other tools. The method is target specific, but it is expected that the marker will use exported symbols to transmit the PC of the marker. The marker makes no guarantees that it will remain with any specific instruction after optimizations. It is possible that the presence of a marker will inhibit optimizations. The intended use is to be inserted after optimizations to allow correlations of simulation runs.

Arguments:

id is a numerical id identifying the marker.

Semantics:

This intrinsic does not modify the behavior of the program. Backends that do not support this intrinisic may ignore it.

'llvm.readcyclecounter' Intrinsic
Syntax:
  declare ulong %llvm.readcyclecounter( )
Overview:

The 'llvm.readcyclecounter' intrinsic provides access to the cycle counter register (or similar low latency, high accuracy clocks) on those targets that support it. On X86, it should map to RDTSC. On Alpha, it should map to RPCC. As the backing counters overflow quickly (on the order of 9 seconds on alpha), this should only be used for small timings.

Semantics:

When directly supported, reading the cycle counter should not modify any memory. Implementations are allowed to either return a application specific value or a system wide value. On backends without support, this is lowered to a constant 0.

Standard C Library Intrinsics

LLVM provides intrinsics for a few important standard C library functions. These intrinsics allow source-language front-ends to pass information about the alignment of the pointer arguments to the code generator, providing opportunity for more efficient code generation.

'llvm.memcpy' Intrinsic
Syntax:
  declare void %llvm.memcpy.i32(sbyte* <dest>, sbyte* <src>,
                                uint <len>, uint <align>)
  declare void %llvm.memcpy.i64(sbyte* <dest>, sbyte* <src>,
                                ulong <len>, uint <align>)
Overview:

The 'llvm.memcpy.*' intrinsics copy a block of memory from the source location to the destination location.

Note that, unlike the standard libc function, the llvm.memcpy.* intrinsics do not return a value, and takes an extra alignment argument.

Arguments:

The first argument is a pointer to the destination, the second is a pointer to the source. The third argument is an integer argument specifying the number of bytes to copy, and the fourth argument is the alignment of the source and destination locations.

If the call to this intrinisic has an alignment value that is not 0 or 1, then the caller guarantees that both the source and destination pointers are aligned to that boundary.

Semantics:

The 'llvm.memcpy.*' intrinsics copy a block of memory from the source location to the destination location, which are not allowed to overlap. It copies "len" bytes of memory over. If the argument is known to be aligned to some boundary, this can be specified as the fourth argument, otherwise it should be set to 0 or 1.

'llvm.memmove' Intrinsic
Syntax:
  declare void %llvm.memmove.i32(sbyte* <dest>, sbyte* <src>,
                                 uint <len>, uint <align>)
  declare void %llvm.memmove.i64(sbyte* <dest>, sbyte* <src>,
                                 ulong <len>, uint <align>)
Overview:

The 'llvm.memmove.*' intrinsics move a block of memory from the source location to the destination location. It is similar to the 'llvm.memcmp' intrinsic but allows the two memory locations to overlap.

Note that, unlike the standard libc function, the llvm.memmove.* intrinsics do not return a value, and takes an extra alignment argument.

Arguments:

The first argument is a pointer to the destination, the second is a pointer to the source. The third argument is an integer argument specifying the number of bytes to copy, and the fourth argument is the alignment of the source and destination locations.

If the call to this intrinisic has an alignment value that is not 0 or 1, then the caller guarantees that the source and destination pointers are aligned to that boundary.

Semantics:

The 'llvm.memmove.*' intrinsics copy a block of memory from the source location to the destination location, which may overlap. It copies "len" bytes of memory over. If the argument is known to be aligned to some boundary, this can be specified as the fourth argument, otherwise it should be set to 0 or 1.

'llvm.memset.*' Intrinsics
Syntax:
  declare void %llvm.memset.i32(sbyte* <dest>, ubyte <val>,
                                uint <len>, uint <align>)
  declare void %llvm.memset.i64(sbyte* <dest>, ubyte <val>,
                                ulong <len>, uint <align>)
Overview:

The 'llvm.memset.*' intrinsics fill a block of memory with a particular byte value.

Note that, unlike the standard libc function, the llvm.memset intrinsic does not return a value, and takes an extra alignment argument.

Arguments:

The first argument is a pointer to the destination to fill, the second is the byte value to fill it with, the third argument is an integer argument specifying the number of bytes to fill, and the fourth argument is the known alignment of destination location.

If the call to this intrinisic has an alignment value that is not 0 or 1, then the caller guarantees that the destination pointer is aligned to that boundary.

Semantics:

The 'llvm.memset.*' intrinsics fill "len" bytes of memory starting at the destination location. If the argument is known to be aligned to some boundary, this can be specified as the fourth argument, otherwise it should be set to 0 or 1.

'llvm.isunordered.*' Intrinsic
Syntax:
  declare bool %llvm.isunordered.f32(float Val1, float  Val2)
  declare bool %llvm.isunordered.f64(double Val1, double Val2)
Overview:

The 'llvm.isunordered' intrinsics return true if either or both of the specified floating point values is a NAN.

Arguments:

The arguments are floating point numbers of the same type.

Semantics:

If either or both of the arguments is a SNAN or QNAN, it returns true, otherwise false.

'llvm.sqrt.*' Intrinsic
Syntax:
  declare double %llvm.sqrt.f32(float Val)
  declare double %llvm.sqrt.f64(double Val)
Overview:

The 'llvm.sqrt' intrinsics return the sqrt of the specified operand, returning the same value as the libm 'sqrt' function would. Unlike sqrt in libm, however, llvm.sqrt has undefined behavior for negative numbers (which allows for better optimization).

Arguments:

The argument and return value are floating point numbers of the same type.

Semantics:

This function returns the sqrt of the specified operand if it is a positive floating point number.

Bit Manipulation Intrinsics

LLVM provides intrinsics for a few important bit manipulation operations. These allow efficient code generation for some algorithms.

'llvm.bswap.*' Intrinsics
Syntax:
  declare ushort %llvm.bswap.i16(ushort <id>)
  declare uint   %llvm.bswap.i32(uint <id>)
  declare ulong  %llvm.bswap.i64(ulong <id>)
Overview:

The 'llvm.bwsap' family of intrinsics is used to byteswap a 16, 32 or 64 bit quantity. These are useful for performing operations on data that is not in the target's native byte order.

Semantics:

The llvm.bswap.16 intrinsic returns a ushort value that has the high and low byte of the input ushort swapped. Similarly, the llvm.bswap.i32 intrinsic returns a uint value that has the four bytes of the input uint swapped, so that if the input bytes are numbered 0, 1, 2, 3 then the returned uint will have its bytes in 3, 2, 1, 0 order. The llvm.bswap.i64 intrinsic extends this concept to 64 bits.

'llvm.ctpop.*' Intrinsic
Syntax:
  declare ubyte  %llvm.ctpop.i8 (ubyte <src>)
  declare ushort %llvm.ctpop.i16(ushort <src>)
  declare uint   %llvm.ctpop.i32(uint <src>)
  declare ulong  %llvm.ctpop.i64(ulong <src>)
Overview:

The 'llvm.ctpop' family of intrinsics counts the number of bits set in a value.

Arguments:

The only argument is the value to be counted. The argument may be of any unsigned integer type. The return type must match the argument type.

Semantics:

The 'llvm.ctpop' intrinsic counts the 1's in a variable.

'llvm.ctlz.*' Intrinsic
Syntax:
  declare ubyte  %llvm.ctlz.i8 (ubyte <src>)
  declare ushort %llvm.ctlz.i16(ushort <src>)
  declare uint   %llvm.ctlz.i32(uint <src>)
  declare ulong  %llvm.ctlz.i64(ulong <src>)
Overview:

The 'llvm.ctlz' family of intrinsic functions counts the number of leading zeros in a variable.

Arguments:

The only argument is the value to be counted. The argument may be of any unsigned integer type. The return type must match the argument type.

Semantics:

The 'llvm.ctlz' intrinsic counts the leading (most significant) zeros in a variable. If the src == 0 then the result is the size in bits of the type of src. For example, llvm.cttz(int 2) = 30.

'llvm.cttz.*' Intrinsic
Syntax:
  declare ubyte  %llvm.cttz.i8 (ubyte <src>)
  declare ushort %llvm.cttz.i16(ushort <src>)
  declare uint   %llvm.cttz.i32(uint <src>)
  declare ulong  %llvm.cttz.i64(ulong <src>)
Overview:

The 'llvm.cttz' family of intrinsic functions counts the number of trailing zeros.

Arguments:

The only argument is the value to be counted. The argument may be of any unsigned integer type. The return type must match the argument type.

Semantics:

The 'llvm.cttz' intrinsic counts the trailing (least significant) zeros in a variable. If the src == 0 then the result is the size in bits of the type of src. For example, llvm.cttz(2) = 1.

Debugger Intrinsics

The LLVM debugger intrinsics (which all start with llvm.dbg. prefix), are described in the LLVM Source Level Debugging document.


Valid CSS! Valid HTML 4.01! Chris Lattner
The LLVM Compiler Infrastructure
Last modified: $Date: 2006/04/20 06:10:31 $